Re: [xsl] Filter out elements that have one specific sub-element and nothing else

["Mukul Gandhi" <gandhi.mukul@xxxxxxxxx>]

Please try the following stylesheet:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"; version="1.0">

<xsl:output method="xml" indent="yes"/>

<xsl:template match="node() | @*">
  <xsl:copy>
    <xsl:apply-templates select="node() | @*" />
  </xsl:copy>
</xsl:template>

<xsl:template match="listitem[formatinfo and
not(*[not(self::formatinfo)]) and (normalize-space() = '')]" />

</xsl:stylesheet>

On 2/21/07, stephan@xxxxxxxxxx <stephan@xxxxxxxxxx> wrote:
> Hi there,
>
> I have an XML file like this:
>
> <?xml version="1.0" encoding="UTF-8"?>
> <funnylist>
>    <listitem>
>        <formatinfo color="yellow" />
>        <stuffinside>Info</stuffinside> MoreInfo
>    </listitem>
>    <listitem>
>        <formatinfo color="blue" />
>    </listitem>
>    <listitem>
>        <formatinfo color="red" />EvenMoreInfo
>    </listitem>
> </funnylist>
>
> I need to filter out this element:
>    <listitem>
>        <formatinfo color="blue" />
>    </listitem>
>
> The rule: if listitem contains only formatinfo and no other element or
> text then remove it.
>
> I have no clue how to formulate the xPath.
> Help appreciated.
> :-) stw


--
Regards,
Mukul Gandhi