Re: [xsl] clever ways to dynamically copy/create element structure as needed?

["Chris Papademetrious christopher.papademetrious@xxxxxxxxxxxx" <xsl-list-service@xxxxxxxxxxxxxxxxxxxxxx>]

Aaand posting again because I forgot the <xsl:copy> on the bmetadatab
template:


  <xsl:mode name="add-data" on-no-match="shallow-copy"/>

  <xsl:template match="topic" mode="add-data">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:apply-templates select="title,titlealts,shortdesc,abstract"/>
      <xsl:apply-templates select="(prolog, parse-xml('&lt;prolog/&gt;'))[1]"
mode="add-data"/>
      <xsl:apply-templates select="body,related-links,topic"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="prolog" mode="add-data">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:apply-templates
select="author,source,publisher,copyright,critdates,permissions"/>
      <xsl:apply-templates
select="(metadata,parse-xml('&lt;metadata/&gt;'))[1]" mode="add-data"/>
      <xsl:apply-templates
select="change-historylist,resourceid,data,sort-as,data-about,foreign,mathml,
svg-container,unknown"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="metadata" mode="add-data">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:apply-templates
select="audience,category,keywords,prodinfo,othermeta"/>
      <xsl:apply-templates select="data[not(@name = 'prefix')]"/>
      <data name="prefix">my-prefix</data>
      <xsl:apply-templates
select="sort-as,data-about,foreign,mathml,svg-container,unknown"/>
    </xsl:copy>
  </xsl:template>


Sorry for all the list noise. I get too excited when my XSLT fiddle worksb&


  *   Chris